LabVIEW 로 Arduino UNO, DUE 사용하기 - Ethernet Shield 와 UDP 통신

LINX 를 사용하여 LabVIEW 와 Arduino 를 연결하는 것을 해보았다. 여기서는 아두이노와 이더넷실드를 결합한 후 UDP 통신으로 PC 에 일정한 데이터를 보내고, PC 에서 아두이노 쪽으로 일정 데이터를 보내는 작업을 해본다.

UDP 혹은 TCP 통신으로 아두이노를 사용하는 것은 일종의 제약을 뛰어넘는 일이다. 이제는 아두이노 혹은 다른 어떤 것이라도 UDP / TCP 통신만 지원된다면 LabVIEW 를 사용하여 제어가 가능하다는 뜻이다.

여기서는 Arduino UNO 뿐만 아니라 Arduino DUE 를 Ethernet Shield 와 결합하여 LabVIEW 와 통신하는 것을 보여준다. 

구글 유투브에 몇개의 동영상이 이러한 통신으로 LabVIEW 와 Arduino 간 신호를 전달하는 것을 보여주고 있다. 하지만 정작 제대로 된 정보는 찾기 어려웠다. 그래서 최대한 간단하게 UDP 를 이용하여 LabVIEW 와 Arduino 간의 신호전달을 만들어 보았다.

하드웨어와 소트드웨어는 다음과 같다. 

PC - LabVIEW with LINX

Arduino UNO + Ethernet Shield + 가변저항(SLIDE Potentiometer) 10k

하드웨어는 최대한 단순하게 해두었다. 가변저항의 양끝은 5V 와 GND 에 연결되었으며, 중간부분은 A0 아날로그 포트로 연결해 두었다. 이더넷실드의 아래에 아두이노 우노가 있다.

실험을 위해 두가지 예제를 여기에 둔다. 

I. 슬라이드 저항 없이 아두이노에서 랜덤하게 나온 값을 LabVIEW 로 전송하는 예제

1. 아두이노 프로그램

/*
 Communication with LabVIEW by UDP Protocol:
 This sketch send udp signal to LabVIEW (PC)

 created 24 Feb 2016
 by JelicleLim 
 http://www.winduino.com
 */
 
#include <SPI.h>         
#include <Ethernet.h>
#include <EthernetUdp.h>  
 
// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = {  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
IPAddress ip(192, 168, 0, 151);
 
unsigned int localPort = 8888;      // local port to listen on
long randomNumber;
 
// buffers for receiving and sending data
char packetBuffer[UDP_TX_PACKET_MAX_SIZE];  //buffer to hold incoming packet,
String  ReplyBuffer;       // a string to send back
char sendBuf[10];
 
 
// An EthernetUDP instance to let us send and receive packets over UDP
EthernetUDP Udp;
 
void setup() {
  Ethernet.begin(mac, ip);    // start the Ethernet and UDP:
  Udp.begin(localPort);
 
  Serial.begin(9600);
  randomSeed(analogRead(5));
}
 
void loop() {
  static int intPulse = 0;
  intPulse++;
  int bufLength;
  // if there's data available, read a packet
  int packetSize = Udp.parsePacket();
  if (packetSize) {
    Serial.print("Received packet of size ");
    Serial.print(packetSize);
    Serial.print(" From ");
    IPAddress remote = Udp.remoteIP();
    for (int i = 0; i < 4; i++) {
      Serial.print(remote[i], DEC);
      if (i < 3) {
        Serial.print(".");
      }
    }
    Serial.print(", port ");
    Serial.print(Udp.remotePort());
 
    // read the packet into packetBufffer
    memset(packetBuffer, 0, UDP_TX_PACKET_MAX_SIZE);
    Udp.read(packetBuffer, UDP_TX_PACKET_MAX_SIZE);
    Serial.print(" Contents:");
    Serial.println(packetBuffer);
 
    // send a reply to the IP address and port that sent us the packet we received
    Udp.beginPacket(Udp.remoteIP(), Udp.remotePort());
    randomNumber = random(5);
    
    if (intPulse%50<25)     ReplyBuffer = String(5+randomNumber);
    else    ReplyBuffer = String(50+randomNumber);
    
    bufLength = ReplyBuffer.length();
    ReplyBuffer.toCharArray(sendBuf,bufLength+2);
    Udp.write(sendBuf);
    Udp.endPacket();
  }
  delay(10);
}
 
 
 

아두이노 IDE 에서 위 예제를 아두이노로 다운로드한다. mac, ip, localport 등은 자신의 환경에 맞게 다시 설정한다.

아두이노 프로그램은 외부에서 아두이노로 UDP 패킷을 보내면 그것을 받아서 보낸쪽으로 다시 회신하는 방식이다. 보낼때 잡음이 섞인 구형파를 만들기 위해 25개의 Low Value 와 25 개의 High Value 를 순차적으로 보낸다.

2. LabVIEW 프로그램

랩뷰쪽 프로그램은 Graphic 기반의 프로그램이라 소스를 설명하거나 보이는 것이 쉽지 않다. 여기에 간단하게 짠 프로그램 화면을 첨부한다.

실제로 프로그램을 만든다면 위와 같이 만들지는 않는다. 여기서는 이렇게 하면 된다는 것만 보이기 위해 모든 랩뷰적 프로그램 방법은 빼고 순차적으로만 넣었다.

a.UDP 를 연다 --> b.아두이노IP를 원하는 값을 쓴다 --> c.UDP를 닫는다. --> d.UDP를 연다 --> e.아두이노에서온값을읽는다 --> f.UDP를 닫는다. --> a로 돌아간다.

기본적으로 데이터전송은 [UDP열기-UDP쓰기-UDP닫기] 로 구성한다. 데이터확인은 [UDP열기-UDP읽기-UDP닫기] 로 구성된다. 여기서 실제 프로그램을 한다면 이렇게 매변 UDP 를 열고 닫을 필요는 없다. 한번 열고 계속 데이터를 읽거나 쓴 후 마지막에 닫아주면 된다. 다시 말하지만 위의 그림은 순서를 보이기 위해 억지로 만들어 둔 그림이다.

실행중인 화면이다. 아두이노에서 데이터를 받아서 그래프를 그린다. 

확인을 위해 아두이노쪽에서도 시리얼통신으로 전송받은 값을 보이도록 프로그램해 두었다. (위 그림 오른쪽 상단)

II. 슬라이드 저항으로 아날로그 인풋 값을 아두이노에서 LabVIEW 로 전송하는 예제

이 예제는 위 I 번에서 아두이노에서 나오는 값이 아날로그포트 0 번에서 나오는 값으로 하고, LabVIEW 쪽 프로그램은 동일하다.

1. 아두이노 프로그램

/*
 Communication with LabVIEW by UDP Protocol:
 This sketch send Analog Value of A0 using udp signal to LabVIEW (PC)

 created 24 Feb 2016
 by JelicleLim 
 http://www.winduino.com
 */
 
#include <SPI.h>         
#include <Ethernet.h>
#include <EthernetUdp.h>  
 
// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = {  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
IPAddress ip(192, 168, 0, 151);
 
unsigned int localPort = 8888;      // local port to listen on
 
// buffers for receiving and sending data
char packetBuffer[UDP_TX_PACKET_MAX_SIZE];  //buffer to hold incoming packet,
String  ReplyBuffer;       // a string to send back
char sendBuf[10];
 
 
// An EthernetUDP instance to let us send and receive packets over UDP
EthernetUDP Udp;
 
void setup() {
  Ethernet.begin(mac, ip);    // start the Ethernet and UDP:
  Udp.begin(localPort);
 
  Serial.begin(9600);
}
 
void loop() {
  int bufLength;
  // if there's data available, read a packet
  int packetSize = Udp.parsePacket();
  if (packetSize) {
    Serial.print("packet size ");
    Serial.print(packetSize);
    Serial.print(" From ");
    IPAddress remote = Udp.remoteIP();
    for (int i = 0; i < 4; i++) {
      Serial.print(remote[i], DEC);
      if (i < 3) {
        Serial.print(".");
      }
    }
    Serial.print(":");
    Serial.print(Udp.remotePort());
 
    // read the packet into packetBufffer
    memset(packetBuffer, 0, UDP_TX_PACKET_MAX_SIZE);
    Udp.read(packetBuffer, UDP_TX_PACKET_MAX_SIZE);
    Serial.print(" Received:");
    Serial.print(packetBuffer);
 
    // send a reply to the IP address and port that sent us the packet we received
    Udp.beginPacket(Udp.remoteIP(), Udp.remotePort());
    ReplyBuffer = String(analogRead(A0));
 
    bufLength = ReplyBuffer.length();
    ReplyBuffer.toCharArray(sendBuf,bufLength+2);
 
    Serial.print(" A0:");
    Serial.print(sendBuf);
    Serial.println();
        
    Udp.write(sendBuf);
    Udp.endPacket();
  }
  delay(10);
}
 
 
 

analogRead(A0) 로 받은 값은 String() 을 통해 문자열로 만들고, 그것을 다시 toCharArray() 로 문자배열로 만들어서 UDP로 전송했다. 나머지는 위 I 번의 예제와 거의 비슷하다.

2. LabVIEW 프로그램

위 I 번 예제와 동일하다. 실행 후 나오는 그래프는 아두이노에서 나오는 신호에 따라 달라진다. 슬라이드로 된 가변저항을 움직이면 그래프는 위와 아래로 변화한다.

III. Arduino DUE 와 Ethernet Shield 의 결합

아두이노 우노와 이더넷 실드를 결합하여 사용한 것과 동일한 방식으로 아두이노 두에(DUE)와 이더넷실드를 결합한 후 UDP 로 LabVIEW 와 통신할 수 있다.

이때 아두이노 프로그램은 동일하다. 

PC 에 Arduino DUE 를 USB로 연결한 후 아두이노 IDE 에서 프로그램한다. [툴 >> 보드] 에 Arduino DUE 가 없다면 [툴>>보드>>보드매니저] 로 들어간 후 DUE 를 검색하여 나오는 것을 설치하면 된다.

보드 설치 후 보드는 Arduino DUE (Programming Port)로 맞추고, 포트는 아두이노 DUE 가 연결된 포트로 맞춘다음 업로드한다. 업로드할 프로그램은 위 I, II 번의 예제 어느 것이든 상관없다. 

LabVIEW 프로그램도 I, II 번의 것과 동일하다.

단 한가지 주의할 것은 Arduino DUE 는 3.3V 전압을 사용하므로 아날로그 인풋에 들어가는 전압이 3.3V 를 넘어서는 안된다. 즉, 슬라이드 가변저항의 양단 끝은 각각 3.3V 와 GND 로 연결 한 후 중간부분을 A0 에 연결해야한다. 5V 에 연결할 경우 DUE 보드가 파손될 수 있다. 전원 부분은 두번, 세번 주의를 기울이도록 한다.

IV. UDP 통신을 이용한 아두이노와 LabVIEW 사용에 관한 소고

TCP 통신을 이용해서도 이와 비슷한 실험이 가능하다. 하지만 UDP 통신을 선택한 것은 두가지 이유인데, 첫째 TCP 보다 쉽다는 것과 둘째, 약간의 전송 에러가 발생해도 괜찮을 데이터라는 가정에서 효율적이기 때문이다.

TCP 통신에 비해 UDP 는 중간에 패킷이 없어져도 크게 신경쓰지 않는다. 그래서 충분히 많은 데이터가 전송될 때, 이를테면 CCTV 같은 영상신호가 갈때, 중간에 한두 프레임정도 빠진다고 해서 크게 문제가 되지는 않는다. 마찬가지로 날씨 데이터를 얻어온다고 할때 1분에 하나씩 데이터가 갈때 한두개 빠진다고 해서 크게 문제가 되지는 않는다.

LabVIEW 를 통해 아두이노라는 지극히 저렴한 장비 - NI 의 하드웨어 가격과 비교하면 아두이노 정말로 껌값이다 - 를 사용할 수 있게 되고, UDP 통신을 통해 멀리 떨어진 곳에 있는 것도 충분히 제어할 수 있다. 물론 여기에 Modbus 등을 추가한다면 더 신뢰성있는 통신이 되겠지만 우선 이것만으로도 개인이 사용하기에는 충분히 괜찮은 장비임에 분명하다.

http://winduino.co.kr

made by JelicleLim (바람)